TTL カメラと Ethernet シールドで作るネットワークカメラ

#include <Adafruit_VC0706.h>
#include <SoftwareSerial.h>   
#include <Ethernet.h>

byte mac[] = { 0xDE,0xAD,0xBE,0xEF,0xF0,0x0D };
EthernetServer server(80);
// CAMERA TX => 2
// CAMERA RX => 3
SoftwareSerial cameraconnection = SoftwareSerial(2, 3);
Adafruit_VC0706 cam = Adafruit_VC0706(&cameraconnection);
boolean camera_found = false;

void setup() {
  Serial.begin(9600);
  
  Ethernet.begin(mac);
  Serial.println(Ethernet.localIP());

  server.begin();

  if( cam.begin() ){
    camera_found = true;
  }
  else{
    return;
  }

}

void loop() {
    
  EthernetClient client = server.available();
  
  if( client ){

    Serial.println("*** New Client ***");
    
    boolean currentLineIsBlank = true;
    boolean requestLineRead = false;
    char reqLine[64];
    char *p = reqLine;
    char *method = NULL;
    char *uri = NULL;
    const char delims[2] = " ";
    memset( reqLine, 0, sizeof(reqLine) );
    
    while( client.connected() ){
      char c = client.read();
      //Serial.write( c );

      // Query
      if( !requestLineRead 
        && ( p - reqLine ) < (sizeof(reqLine) - 1) 
        && c != '\r' 
        && c != '\n' ){
        *p = c;
        p++;
      }
      
      if( c == '\n' && currentLineIsBlank ){

        // Parse Query
        p = strtok(reqLine, delims);
        while( p ){
          if( !method ){
            method = p;
          }
          else if( !uri ){
            uri = p;
          }
          p = strtok(NULL, delims);
        }

        // Send Response
        if( camera_found && !strcmp(method, "GET") && !strcmp(uri, "/pic") ){

          cam.setImageSize(VC0706_320x240);

          if( cam.takePicture() ){

            uint16_t jpglen = cam.frameLength();
            String s = "Content-Length: ";
            s += jpglen;
            
            client.println("HTTP/1.1 200 OK");
            client.println("Content-Type: image/jpeg");
            client.println( s );
            client.println("Connection: close");
            client.println();

            byte wCount = 0;
            while (jpglen > 0) {
              uint8_t *buf;
              uint8_t bytesToRead = min(64, jpglen);
              buf = cam.readPicture(bytesToRead);

              client.write(buf, bytesToRead);
              
              jpglen -= bytesToRead;
            }

            cam.reset();
          }
          else {
            client.println("HTTP/1.1 500 Server Internal Error");
            client.println("Content-Type: text/plain");
            client.println("Connection: close");
            client.println();
            client.println("I'm sorry :(");
          }
          
        }
        else{
          client.println("HTTP/1.1 404 Not Found");
          client.println("Content-Type: text/plain");
          client.println("Connection: close");
          client.println();
          client.println("File Not Found");
        }
        
        break;
      }
      if( c == '\n' ){
        currentLineIsBlank = true;
        if( !requestLineRead ){
          requestLineRead = true;
        }
      }
      else if( c != '\r' ){
        currentLineIsBlank = false;
      }
    }
    
    delay( 10 );
    client.stop();
    
    Serial.println("Client disconnected");

  }

}